// wanderer.txt
// A very simple, naive text. Just wanders around.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.

begincreaturescript;

variables;

short i,respawn,target;

body;

beginstate INIT_STATE;

	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);

set_script_mode(2);
add_char_to_group(ME,1);

	break;

beginstate DEAD_STATE;

if (my_number() <= 11)
 spawn_creature((my_number() + 5));
else
 spawn_creature((my_number() - 5));

break;

beginstate START_STATE; 

set_attitude(ME,4);

if ((get_sdf(1,19) == 0) && (can_see_char(1000) == 0)) {
 set_flag(1,19,1);
 message_dialog("Ahead is an very thin Nephilim wandering mindlessly. It's body is alive, preserved by strange magic, but it seems to have no mind. This was probably the fate of the original inhabitants of this city.","Fortunately, it makes no move to attack you. It cannot think after all.");
}

	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}	

	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;